
EDB_ROOT	= ../..

TEMPLATE	= lib
CONFIG		+= plugin
#CONFIG		+= silent
DESTDIR		= $$EDB_ROOT
INSTALLS	+= target

DEFINES += EDB_PLUGIN

# ignore missing symbols, they'll be found when linked into edb
linux-g++*:QMAKE_LFLAGS -= $$QMAKE_LFLAGS_NOUNDEF
linux-g++*:QMAKE_LFLAGS -= "-Wl,--no-undefined"

# link to edb
win32:LIBS +=	$$EDB_ROOT/edb.lib
win64:LIBS +=	$$EDB_ROOT/edb.lib

unix {
	INCLUDEPATH	+= $$EDB_ROOT/include/os/unix $$EDB_ROOT/include $$EDB_ROOT/include/arch/$$QT_ARCH $$EDB_ROOT/include/arch/$$QT_ARCH/edisassm /usr/local/include/
	DEPENDPATH	+= $$EDB_ROOT/include/os/unix $$EDB_ROOT/include $$EDB_ROOT/include/arch/$$QT_ARCH $$EDB_ROOT/include/arch/$$QT_ARCH/edisassm
	
	include(plugins-$${QT_ARCH}.pri)
}

win32 {
	INCLUDEPATH	+= $$EDB_ROOT/include/os/win32 $$EDB_ROOT/include $$EDB_ROOT/include/arch/i386 $$EDB_ROOT/include/arch/i386/edisassm "c:/Program Files (x86)/boost/boost_1_39/"
	DEPENDPATH	+= $$EDB_ROOT/include/os/win32 $$EDB_ROOT/include $$EDB_ROOT/include/arch/i386 $$EDB_ROOT/include/arch/i386/edisassm 
}

win64 {
	INCLUDEPATH	+= $$EDB_ROOT/include/os/win64 $$EDB_ROOT/include $$EDB_ROOT/include/arch/x86_64 $$EDB_ROOT/include/arch/x86_64/edisassm "c:/Program Files (x86)/boost/boost_1_39/"
	DEPENDPATH	+= $$EDB_ROOT/include/os/win64 $$EDB_ROOT/include $$EDB_ROOT/include/arch/x86_64 $$EDB_ROOT/include/arch/x86_64/edisassm
}

macx {
	INCLUDEPATH	+= $$EDB_ROOT/include/os/osx $$EDB_ROOT/include $$EDB_ROOT/include/arch/i386 $$EDB_ROOT/include/arch/i386/edisassm
	DEPENDPATH	+= $$EDB_ROOT/include/os/osx $$EDB_ROOT/include $$EDB_ROOT/include/arch/i386 $$EDB_ROOT/include/arch/i386/edisassm
}
